免费视频淫片aa毛片_日韩高清在线亚洲专区vr_日韩大片免费观看视频播放_亚洲欧美国产精品完整版

1.根據(jù)序號(hào)查找姓名

公式：

=XLOOKUP(H2,$A$2:$A$8,$C$2:$C$8)

=LOOKUP(1,0/(H2=$A$2:$A$8),$C$2:$C$8)

基本語(yǔ)法有點(diǎn)類(lèi)似，核心的內(nèi)容幾乎一樣。

=XLOOKUP(查找值,查找區(qū)域,返回區(qū)域)

=LOOKUP(1,0/(查找值=查找區(qū)域),返回區(qū)域)

2.反向查找，根據(jù)姓名查找所屬部門(mén)

對(duì)于XLOOKUP和LOOKUP，沒(méi)有正反向的區(qū)別，用法都一樣。

=XLOOKUP(H2,$C$2:$C$8,$B$2:$B$8)

=LOOKUP(1,0/(H2=$C$2:$C$8),$B$2:$B$8)

3.橫向查找，根據(jù)基礎(chǔ)工資、應(yīng)發(fā)合計(jì)，查找對(duì)應(yīng)的金額

對(duì)于XLOOKUP和LOOKUP，也支持橫向查找。

=XLOOKUP(I$1,$D$1:$F$1,$D$2:$F$2)

=LOOKUP(1,0/(I$1=$D$1:$F$1),$D$2:$F$2)

4.多列多行查找，根據(jù)姓名，按順序查找對(duì)應(yīng)的3列金額

返回區(qū)域不鎖定D列，這樣右拉就變成E列、F列，從而可以查找3列的金額。

=XLOOKUP($H2,$C$2:$C$8,D$2:D$8)

=LOOKUP(1,0/($H2=$C$2:$C$8),D$2:D$8)

5.多條件查找，根據(jù)所屬部門(mén)、姓名查找應(yīng)發(fā)合計(jì)

多條件就用&將所有條件合并起來(lái)，再合并所有條件區(qū)域。

=XLOOKUP(H2&I2,$B$2:$B$8&$C$2:$C$8,$F$2:$F$8)

=LOOKUP(1,0/(H2&I2=$B$2:$B$8&$C$2:$C$8),$F$2:$F$8)

到目前為止，兩者幾乎沒(méi)區(qū)別，作用一樣，公式長(zhǎng)短也幾乎一樣。后面的案例，開(kāi)始有區(qū)別。

6.找不到對(duì)應(yīng)值的處理，多條件查找，根據(jù)所屬部門(mén)、姓名查找應(yīng)發(fā)合計(jì)

跟案例5一樣，只是增加了一行沒(méi)有對(duì)應(yīng)值。

公式：XLOOKUP增加了第4參數(shù)，讓錯(cuò)誤值顯示空白。LOOKUP借助IFERROR，讓錯(cuò)誤值顯示空白。

=XLOOKUP(H2&I2,$B$2:$B$8&$C$2:$C$8,$F$2:$F$8,"")

=IFERROR(LOOKUP(1,0/(H2&I2=$B$2:$B$8&$C$2:$C$8),$F$2:$F$8),"")

語(yǔ)法：

=XLOOKUP(查找值,查找區(qū)域,返回區(qū)域,"錯(cuò)誤值顯示值")

=IFERROR(LOOKUP(1,0/(查找值=查找區(qū)域),返回區(qū)域),"錯(cuò)誤值顯示值")

XLOOKUP在這里略有優(yōu)勢(shì)。

7.查找所屬部門(mén)，最后一次出現(xiàn)的姓名

公式：

=XLOOKUP(E2,$B$2:$B$8,$C$2:$C$8,,,-1)

=LOOKUP(1,0/(E2=$B$2:$B$8),$C$2:$C$8)

XLOOKUP完整的語(yǔ)法有6個(gè)參數(shù)，第4、5參數(shù)這里不需要可以空著，第6參數(shù)-1，意思就是查找最后的值。

8.按績(jī)效判斷對(duì)應(yīng)區(qū)間的等級(jí)

公式：

=XLOOKUP(E2,$A$2:$A$5,$C$2:$C$5,,-1)

=LOOKUP(E2,$A$2:$A$5,$C$2:$C$5)

第5參數(shù)為-1，代表按區(qū)間查找。

9.根據(jù)簡(jiǎn)稱(chēng)查找全稱(chēng)的對(duì)應(yīng)值

公式：

=XLOOKUP("*"&D2&"*",$A$2:$A$3,$B$2:$B$3,,2)

=LOOKUP(1,0/FIND(D2,$A$2:$A$3),$B$2:$B$3)

語(yǔ)法說(shuō)明，XLOOKUP第1參數(shù)加通配符，第5參數(shù)設(shè)置為2，才能按通配符匹配。

從上面9個(gè)案例可以看出，這2個(gè)函數(shù)旗鼓相當(dāng)，并沒(méi)有誰(shuí)取得絕對(duì)優(yōu)勢(shì)。在實(shí)際工作中，用自己最熟悉的函數(shù)就是最好的。

請(qǐng)把「Excel不加班」推薦給你的朋友